Расшифровка отчета на СКД с детализацией по выбранному полю на основе БСП

Публикация № 1038792

Разработка - Практика программирования

СКД Расшифровка Программная расшифровка Отчет ОбработкаРасшифровкиКомпановкиДанных

В данной статье рассмотрим механизм работы с расшифровкой отчета, созданного при помощи системы компоновки данных, в управляемом приложении. Показывать буду на примере реальной задачи. Условие: использовать имеющиеся в конфигурации механизмы БСП, с минимальными и "правильными" изменениями. Расшифровка должны быть двух видов на каждом поле: 1. Открывать ссылочный объект 2. Открывать новую форму с детализацией табличной части документа. Собственно ради второго пункта и писалась статья, в основном для себя, чтобы не забыть.

Подробно рассматривать все настройки схемы компоновки мы не будем, остановимся только на том, ради чего была сделана статья.

Имеется некий отчет, у него схема компоновки данных, наборы данных, ресурсы, Параметры, Настройки.

Основные настройки отчета:

1. Рассмотрим вкладку «Макеты» основной схемы компоновки данных.

В макете описано каждое поле, для того что бы можно было сделать расшифровку по ним.

Если поле не ссылочного типа:

- В параметре расшифровки указываем наименование параметра

- В параметрах макета в поле Выражение делаем выбор

- В Параметр расшифровки в поле Выражение указываем ссылку на документ, по которому будет производиться расшифровка.

Если поле ссылочного типа:

Все тоже самое, только в Параметр расшифровки добавляем 2 параметра:

- Один из низ это ссылка на элемент указанный в поле

- Второй это ссылка на документ, по которому будет производиться расшифровка

На этом со схемой компоновки данных закончили.

3. Формы в отчете я использовал БСПшные, только для расшифровки создал свою форму "ФормаРасшифровки" с типом «Форма Отчета»

4. Открываем основную форму отчета БСП, для элемента формы «ОтчетТабличныйДокумент»  ищем событие «ОбработкаРасшифровки» и переходим в нее.

В открывшейся процедуре вызываем процедуру обработки в переопределяемом модуле.

ОтчетыКлиентПереопределяемый.ОбработкаРасшифровки(ЭтотОбъект, Элемент, Расшифровка, СтандартнаяОбработка);

5. Проверяем имя отчета, при необходимости подсистему на существование, определяем модуль дальнейшей обработки и вызываем из него следующую процедуру.

Процедура ОбработкаРасшифровки(ФормаОтчета, Элемент, Расшифровка, СтандартнаяОбработка) Экспорт
	
	Если ФормаОтчета.НастройкиОтчета.ПолноеИмя = "Отчет.ДвижениеМаркированногоТовара" Тогда
		
		Если ОбщегоНазначенияКлиент.ПодсистемаСуществует(
			"ТакскомПодсистемы.ЭлектронныйДокументооборот.РеализацияМаркированнойПродукции") Тогда
			
			МодульРеализацияМаркированнойПродукцииКлиент = 
				ОбщегоНазначенияКлиент.ОбщийМодуль("РеализацияМаркированнойПродукцииКлиент");
		
			МодульРеализацияМаркированнойПродукцииКлиент.ОбработкаРасшифровкиОтчетаДвижениеМаркированногоТовара(
				ФормаОтчета, Расшифровка, СтандартнаяОбработка);
				
		КонецЕсли;
				
	КонецЕсли;		
	
КонецПроцедуры

6. Полный код вызываемой процедуры:

Процедура ОбработкаРасшифровкиОтчетаДвижениеМаркированногоТовара(ФормаОтчета, Расшифровка, СтандартнаяОбработка) Экспорт
	
	СтандартнаяОбработка = Ложь;
	
	ОбработкаРасшифровки = Новый ОбработкаРасшифровкиКомпоновкиДанных(
		ФормаОтчета.ОтчетДанныеРасшифровки,
		Новый ИсточникДоступныхНастроекКомпоновкиДанных(ФормаОтчета.Отчет));
		
	ДополнительныеПараметры = Новый Структура;
	ДополнительныеПараметры.Вставить("Расшифровка", Расшифровка);
	ДополнительныеПараметры.Вставить("ОтчетДанныеРасшифровки", ФормаОтчета.ОтчетДанныеРасшифровки);
	ДополнительныеПараметры.Вставить("ФормаОтчета", ФормаОтчета);
		
	ОписаниеОповещения = Новый ОписаниеОповещения("ПоказатьВыборДействияЗавершение", ЭтотОбъект, ДополнительныеПараметры);
	
	ДоступныеДействия = Новый Массив;
	ДоступныеДействия.Добавить(ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение);
	
	ДополнительныеПунктыМеню = Новый СписокЗначений;
	ДополнительныеПунктыМеню.Добавить("КодыМаркировки", НСтр("ru = 'Коды маркировки документа'"));
	
	ОбработкаРасшифровки.ПоказатьВыборДействия(ОписаниеОповещения, Расшифровка, ДоступныеДействия, ДополнительныеПунктыМеню); 
		
КонецПроцедуры

Разберем подробно код процедуры

Прежде всего отменяем стандартную обработку:

СтандартнаяОбработка = Ложь;

Создаем обработку расшифровки:

ОбработкаРасшифровки = Новый ОбработкаРасшифровкиКомпоновкиДанных(
		ФормаОтчета.ОтчетДанныеРасшифровки,
		Новый ИсточникДоступныхНастроекКомпоновкиДанных(ФормаОтчета.Отчет));

 Создаем ОписаниеОповещения с параметрами, для алгоритма после выбора действия пользователем:

ДополнительныеПараметры = Новый Структура;
ДополнительныеПараметры.Вставить("Расшифровка", Расшифровка);
ДополнительныеПараметры.Вставить("ОтчетДанныеРасшифровки", ФормаОтчета.ОтчетДанныеРасшифровки);
ДополнительныеПараметры.Вставить("ФормаОтчета", ФормаОтчета);
		
ОписаниеОповещения = Новый ОписаниеОповещения("ПоказатьВыборДействияЗавершение", ЭтотОбъект, ДополнительныеПараметры);

Добавляем два действия, одно платформенное, другое создаем свое собственное "КодыМаркировки":

ДоступныеДействия = Новый Массив;
ДоступныеДействия.Добавить(ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение);
	
ДополнительныеПунктыМеню = Новый СписокЗначений;
ДополнительныеПунктыМеню.Добавить("КодыМаркировки", НСтр("ru = 'Коды маркировки документа'"));

Вызываем меню выбора действий:

ОбработкаРасшифровки.ПоказатьВыборДействия(ОписаниеОповещения, Расшифровка, ДоступныеДействия, ДополнительныеПунктыМеню);

7. В обработке оповещения обрабатываем каждый пункт меню действий

- В первом случае просто открываем объект по ссылке

- Во втором вызываем процедуру, которая нам вернет выбранное поле.

И если Выбранное поле заполнено, тогда вызываем процедуру открывающую новую форму отчета.

Процедура ПоказатьВыборДействияЗавершение(ВыполненноеДействие, ПараметрВыполненногоДействия, ДополнительныеПараметры) Экспорт
		
	Если ВыполненноеДействие = ДействиеОбработкиРасшифровкиКомпоновкиДанных.ОткрытьЗначение Тогда
		
		ПоказатьЗначение(Неопределено, ПараметрВыполненногоДействия);
		
	ИначеЕсли ВыполненноеДействие = "КодыМаркировки" Тогда
		
		ВыбранноеПоле = РеализацияМаркированнойПродукцииВызовСервера.ОбработкаРасшифровкиОтчетаДвижениеМаркированногоТовара(
			ДополнительныеПараметры.ОтчетДанныеРасшифровки, ДополнительныеПараметры.Расшифровка);
		
		Если ВыбранноеПоле = Неопределено Тогда
			Возврат
		КонецЕсли;
		
		ОткрытьОтчетРасшифровкуПоВыбранномуПолю(ДополнительныеПараметры.ФормаОтчета, ВыбранноеПоле);
		
	КонецЕсли;
	
КонецПроцедуры

Т.к. функция получения выбранного поля  находится в общем модуле с галочкой Вызов Сервера, то делаем там только инициализацию серверной функции

Функция ОбработкаРасшифровкиОтчетаДвижениеМаркированногоТовара(ОтчетДанныеРасшифровки, Расшифровка) Экспорт
	
	Возврат РеализацияМаркированнойПродукцииСервер.ПолеРасшифровкиОтчетаДвижениеМаркированногоТовара(
		ОтчетДанныеРасшифровки, Расшифровка)
	
КонецФункции

А уже в серверном общем модуле, описываем алгоритм получения выбранного поля Документ поступления.

Функция ПолеРасшифровкиОтчетаДвижениеМаркированногоТовара(ОтчетДанныеРасшифровки, Расшифровка) Экспорт
	
	ДанныеРасшифровки = ПолучитьИзВременногоХранилища(ОтчетДанныеРасшифровки);
	ПоляРасшифровки = ДанныеРасшифровки.Элементы.Получить(Расшифровка).ПолучитьПоля();
	
	НайденноеПоле = ПоляРасшифровки.Найти("ДокументПоступления");
	Если НайденноеПоле = Неопределено Тогда
		Возврат Неопределено;
	Иначе
		Возврат НайденноеПоле.Значение;
	КонецЕсли;
	
КонецФункции

 

8. Процедура инициализирует открытие формы отчета с передачей параметров.

Процедура ОткрытьОтчетРасшифровкуПоВыбранномуПолю(ФормаОтчета, ВыбранноеПоле)
	
	Отбор = Новый Структура;
	Отбор.Вставить("ДокументСсылка", ВыбранноеПоле);
	
	ПараметрыФормы = Новый Структура;
	ПараметрыФормы.Вставить("Отбор", Отбор);
	ПараметрыФормы.Вставить("КлючНазначенияИспользования", "КодыМаркировки");
	
	ОткрытьФорму(
		"Отчет.ДвижениеМаркированногоТовара.Форма.ФормаРасшифровки", ПараметрыФормы, ФормаОтчета, ФормаОтчета.УникальныйИдентификатор);
		
КонецПроцедуры

9. В модуле открывшейся формы процедура ПриСозданииНаСервере:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Если Параметры.Свойство("АвтоТест") Тогда
		Возврат;
	КонецЕсли;
	
	СтандартнаяОбработка = Ложь;
	
	Запрос = "";
	Если Параметры.Отбор.Свойство("ДокументСсылка") Тогда        
		Запрос = СформироватьДинамическиЗапрос(Параметры.Отбор.ДокументСсылка);
	КонецЕсли;
	Если Запрос = "" Тогда
		Возврат;
	КонецЕсли;
	
	Схема = Отчеты.ДвижениеМаркированногоТовара.ПолучитьМакет("РасшифровкаКодыМаркировки");
	Схема.НаборыДанных[0].Запрос = Запрос;   
		
	//Из схемы возьмем настройки по умолчанию
	Настройки = Схема.НастройкиПоУмолчанию;
	Для Каждого СтрокаОтбора Из Параметры.Отбор Цикл
		
		Отбор = Настройки.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
		Отбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных(СтрокаОтбора.Ключ);
		Отбор.ПравоеЗначение = СтрокаОтбора.Значение;
		
	КонецЦикла;
	
	//Формируем макет, с помощью компоновщика макета
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	
	//Передаем в макет компоновки схему, настройки и данные расшифровки
	МакетКомпоновки = КомпоновщикМакета.Выполнить(Схема, Настройки);
		
	//Выполним компоновку с помощью процессора компоновки
	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки);
	
	//Очищаем поле табличного документа
	Результат.Очистить();
	
	//Выводим результат в табличный документ
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(Результат);
	
	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);
		
	АвтоЗаголовок = Ложь;
	Заголовок = НСтр("ru = 'Коды операций (расшифровка)'");
	
КонецПроцедуры

Разберем ключевые строки процедуры:

- Проверяем параметры формы, и вызываем формирование динамического запроса по полученному параметру ссылки на документ.

Запрос = "";
Если Параметры.Отбор.Свойство("ДокументСсылка") Тогда        
	Запрос = СформироватьДинамическиЗапрос(Параметры.Отбор.ДокументСсылка);
КонецЕсли;
Если Запрос = "" Тогда
	Возврат;
КонецЕсли;

- Процедура формирования динамического запроса:

&НаСервере
Функция СформироватьДинамическиЗапрос(ДокументСсылка)
	
	ШаблонЗапроса = "ВЫБРАТЬ
	                |	КодыМаркировки.Ссылка КАК ДокументСсылка,
					|	КодыМаркировки.НомерСтроки КАК НомерСтроки,
	                |	КодыМаркировки.СерийныйНомер КАК СерийныйНомер
	                |ИЗ
	                |	Документ.%1.КодыМаркировки КАК КодыМаркировки";
	
	Запрос = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
		ШаблонЗапроса,
		ДокументСсылка.Метаданные().Имя);
		
	Возврат Запрос;	
	
КонецФункции

- Получаем макет скд и в первом наборе данных переопределяем запрос, на тот, что мы сформировали динамически выше.

Схема = Отчеты.ДвижениеМаркированногоТовара.ПолучитьМакет("РасшифровкаКодыМаркировки");
Схема.НаборыДанных[0].Запрос = Запрос;

Посмотрим на вкладку "Наборы данных" полученного макета расшифровки и видим что запрос в нем это лишь шаблон, т.к. мы заранее не знаем какой тип

документа будет расшифровываться. На вкладке "Настройки" вывод детальных записей, больше настроек у этой схемы нет.

- Применяем настройки и добавляем полученный в параметрах отбор

//Из схемы возьмем настройки по умолчанию
Настройки = Схема.НастройкиПоУмолчанию;
Для Каждого СтрокаОтбора Из Параметры.Отбор Цикл
		
	Отбор = Настройки.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
	Отбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных(СтрокаОтбора.Ключ);
	Отбор.ПравоеЗначение = СтрокаОтбора.Значение;
		
КонецЦикла;

- После располагается типовой код по программному формированию отчета,

куда мы передаем полученную схему, и сформированные настройки отчета.

 

P.S.

Статья, по формированию расшифровки, без использования БСП

Работа с расшифровкой отчета на СКД

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо развёрнутое
Свернуть все
1. artms 208 04.09.19 09:12 Сейчас в теме
Получение данных из документов, не зачет на экзамене, нужно было сделать регистр сведений, событием. Возможно здесь приводится отчет встроенный но "СформироватьДинамическиЗапрос" это мягко говоря не верно. Новый запрос, нужно сделать либо как отчет № 2 либо как второй набор данных передав параметр "КлючТекущегоВарианта", настройки. Параметры отчета нужно было передать через параметр "ПользовательскиеНастройки,Отбор", а не кодом "ПриСозданииНаСервере". Тогда ваш код не нужен почти весь, достаточно правильно настроить отчет № 2 или вариант. И сделать заполнение пользовательских настроек, полученных на основании расшифровки отчета № 2. Конечно, возможно автор пытался минимально изменить конфигурацию и это частично его оправдывает, но не оправдывает вторую часть публикации.
FirePyres; +1 Ответить
2. Viktor_Ermakov 176 04.09.19 23:47 Сейчас в теме
(1)Спасибо Вам за отзыв.
1. "Получение данных из документов, не зачет на экзамене, нужно было сделать регистр сведений, событием" - тут Вы правы, но это уже тема архитектуры, в рамках которой я был ограничен.
2. "СформироватьДинамическиЗапрос" - чем это плохо, поясните, ведь я заведомо не знаю тип документа по которому мне нужно получить расшифровку, поэтому формирую динамический запрос. Это кстати стандартная практика типовых решений в настоящее время.
3. "Новый запрос, нужно сделать либо как отчет № 2 либо как второй набор данных передав параметр "КлючТекущегоВарианта"" - это уже тонкости, вариации решения. Я против отчета №2, а вот второй набор можно сделать, но не вижу ничего плохого во второй схеме компоновки.
4. "Параметры отчета нужно было передать через параметр "ПользовательскиеНастройки,Отбор", а не кодом "ПриСозданииНаСервере"" - то что использовать нужно пользовательские настройки это да. Но что значит передать, я не понял.

Резюмирую: да, скорее всего представленный алгоритм можно улучшить, оптимизировать, я могу чего то не знать еще, все приходит с опытом.
Цель статьи была показать как в дорабатываемой конфигурации на БСП сделать отчет с расшифровкой, минимизируя изменения объектов на поддержке.
Designer1C; +1 Ответить
3. artms 208 05.09.19 13:21 Сейчас в теме
(2)
что значит передать,

2. "СформироватьДинамическиЗапрос" - это к получению данных из документов, в логике формирования запроса динамически нет никаких нарушений.
4.Делал открытие отчета СКД с заполнением параметров и отборами так :
// в общем модуле на сервере
Функция УстановитьПользовательскиеНастройкиОтчета(ТипОтчета,СтруктураПараметров)
	
	СтруктураНастроек = Новый Структура;
	ОтчетОбъект = Отчеты[ТипОтчета].Создать();
	
	ПользовательскиеНастройки = ОтчетОбъект.КомпоновщикНастроек.ПользовательскиеНастройки;
	Для Каждого ЭлПараметр  Из СтруктураПараметров Цикл
		Для Каждого ПараметрСКД Из ПользовательскиеНастройки.Элементы Цикл
			Если ТипЗнч(ПараметрСКД) = Тип("ЗначениеПараметраНастроекКомпоновкиДанных") Тогда  
				Если строка(ПараметрСКД.Параметр) = ЭлПараметр.Ключ Тогда 
					ПараметрСКД.Значение = ЭлПараметр.Значение;
					ПараметрСКД.Использование = Истина;
				КонецЕсли;
			КонецЕсли;
		КонецЦикла;
	КонецЦикла;
	
	Возврат ПользовательскиеНастройки;
	
КонецФункции

&НаКлиенте
Процедура ОткрытьЦелевойПрием()

	СтрПараметры = Новый Структура;
	СтрПараметры.Вставить("ПриемнаяКампания", Объект.Ссылка);
		
	ПользовательскиеНастройки = УстановитьПользовательскиеНастройкиОтчета("ПК_ЦелевойПрием",СтрПараметры);
		
	Отбор = Новый Структура;
	Отбор.Вставить("Специальность");
	Отбор.Вставить("УсловияОбучения");
	ЗначенияКлючейРегистра = ЗначенияКлючейРегистра(ВыбраннаяСтрока,Отбор);
		
	ПараметрыФормы = Новый Структура("Отбор,ПользовательскиеНастройки, СформироватьПриОткрытии", Отбор,ПользовательскиеНастройки, Истина);
		
	ОткрытьФорму("Отчет.ПК_ЦелевойПрием.ФормаОбъекта", ПараметрыФормы); 
	
КонецПроцедуры
Показать


(УстановитьПользовательскиеНастройкиОтчета - сделана не рекурсивно, т.к. группы условий это не стандартные наборы параметров и их даже если есть устанавливать не нужно, так было принято)
6. Viktor_Ermakov 176 05.09.19 15:59 Сейчас в теме
(3) Спасибо за пояснения, учтем.
4. bmk74 141 05.09.19 15:12 Сейчас в теме
Хм ну и заморочки, так то уже все решено за вас
Ссылка на статью .
Добавить в расширение, единственное они в стандартном варианте почему то не сделали ключ варианта нельзя передать в открываемый отчет, но и это можно добавить...
5. Viktor_Ermakov 176 05.09.19 15:57 Сейчас в теме
(4) Во первых не совсем понял как Ваше решение покрывает задачу в данной статье?
У меня в расшифровке строится запрос к ТЧ документа, тип которого мне заранее не известен, поэтому запрос формируется динамически.

Во вторых о каком расширении может идти речь, если ты разрабатываешь свою конфигурацию на БСП.
Оставьте свое сообщение

См. также

3 онлайн-курса по 1С-программированию: обмен данными, расчетные задачи и бухгалтерские задачи с 12 мая по 8 июля 2020 г. Промо

Практика программирования v8 Бесплатно (free)

Пакет из 3-х курсов по 1С-программированию. Основная цель - сформировать у слушателей практические навыки, связанные с реализацией задач обмена для прикладных решений, работающих на платформе “1С:Предприятие”, а также с разработкой прикладных решений, предназначенных для автоматизации расчета заработной платы и задач бухгалтерского учета.

22.04.2020    3152    23    infostart    2    

Универсальные инструменты 1С

Универсальные обработки Прочие инструменты разработчика v8 1cv8.cf Бесплатно (free)

Свободно распространяемый набор универсальных обработок и отчетов в виде расширения для разработки и поддержки, которое работает во ВСЕХ видах клиентских приложений и во всех операционных системах, которые поддерживает платформа 1С:Предприятие, кроме мобильных. Консоль запросов - консоль отчетов - консоль кода - редактор объектов базы данных - удаление помеченных объектов - поиск и удаление дублей - редактор констант - консоль заданий - групповая обработка справочников и документов - динамический список - поиск ссылок на объект - регистрация изменений для обмена данными - структура хранения базы - консоль HTTP запросов-консоль вебсервисов- консоль сравнения данных- информация о лицензиях- загрузка из табличного документа-файловый менеджер-все функции- навигатор по конфигурации-конструктор регулярных выражений-Выгрузка загрузка XML с фильтрами

21.01.2020    18270    295    cprit    84    

[СКД] Программное создание схемы компоновки данных

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Сделаем отчет на СКД полностью программно, без использования макета "схема компоновки данных".

15.01.2020    15481    0    John_d    22    

Таблица значений. Нюансы

Практика программирования v8 Бесплатно (free)

Обзор некоторых аспектов использования общеизвестного инструмента 1С.

01.10.2019    25258    0    Yashazz    44    

Онлайн-курс "1С:Специалист-консультант по "1С:Зарплата и управление персоналом" 22-25 июня 2020 года Промо

Решение задач на 1С:Специалист Бухгалтерский учет Зарплата Управление персоналом (HRM) v8 v8::СПР ЗУП3.x БУ УУ Бесплатно (free)

Спрос на специалистов по внедрению "1С:Зарплата и управление персоналом 8" с каждым днем растет. Станьте одним из востребованных специалистов - пройдите обучение по актуальной редакции 1C:ЗУП 3.1.

13200 руб.

14.06.2018    10007    3    5    

СКД. Отчеты с картинками

Практика программирования Работа с интерфейсом v8::СКД 1cv8.cf Бесплатно (free)

Решение популярных кейсов с картинками в отчетах на СКД.

25.09.2019    15950    0    YPermitin    33    

[Шпаргалка] Программное создание элементов формы

Практика программирования Работа с интерфейсом v8 1cv8.cf Бесплатно (free)

Программное создание практически всех популярных элементов формы.

06.09.2019    34604    0    rpgshnik    59    

Агрегатные функции СКД, о которых мало кто знает

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    36760    0    ids79    52    

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    55617    0    ids79    37    

Обработчики событий при записи объектов. Зачем и что за чем?

Математика и алгоритмы v8 Бесплатно (free)

Программисту, имеющему немного опыта на платформе 1С 8.3, бывает сложно разобраться: ПередЗаписью, ПриЗаписи, ПослеЗаписи, на сервере, на клиенте, в модуле формы, в модуле объекта.... Эта шпаргалка была создана в процессе обучения и реального опыта с целью разложить всё по полочкам, чтобы было четкое понимание в каком случае какой обработчик нужно использовать и в какой последовательности они запускаются при записи и проведении документов. Данная статья будет полезна в большей степени начинающим разработчикам. Но и опытным позволит освежить информацию, упорядочить её.

25.07.2019    35310    4    AlbinaAAA    25    

Как прикрутить ГУИД к регистру сведений

Практика программирования Перенос данных из 1C8 в 1C8 Разработка v8 Бесплатно (free)

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    17725    0    m-rv    17    

Подсистема "Инструменты разработчика" v5.34 Промо

Инструментарий разработчика v8 1cv8.cf Бесплатно (free)

Интегрированный набор инструментов разработчика: - консоль кода - консоль запросов - консоль построителя отчетов - консоль компоновки данных - консоль заданий - конструктор запроса - справочник алгоритмов - исследователь объектов - интерфейсная панель - настройка журнала регистрации - анализ журнала регистрации - настройка техножурнала - анализ техножурнала - подбор и обработка объектов - редактор объекта БД - редактор констант - редактор параметров сеанса - редактор изменений по плану обмена - редактор пользователей - редактор предопределенных - редактор хранилищ настроек - динамический список - поиск дублей и замена ссылок - контекстная подсказка - синтакс-помощник - поиск битых ссылок - поиск ссылок на объект - структура хранения БД - удаление объектов с контролем ссылок - и прочее

23.09.2007    475775    4340    tormozit    2664    

Excel vs 1С: битва с неожиданным исходом

Анализ учета Универсальные обработки Загрузка и выгрузка в Excel Финансовые Управленческие v8 1cv8.cf Россия Бесплатно (free)

Что лучше 1С или Excel? Разберемся, в казалось бы, очевидном, чтобы получить невероятное!

11.04.2019    33728    0    bolefirenko    116    

Информирование пользователя. Работа с объектом «СообщениеПользователю»

Практика программирования Разработка v8::УФ 1cv8.cf Бесплатно (free)

Различные варианты и нюансы использования объекта СообщениеПользователю и другие способы информирования пользователя: без привязки к какой-либо форме и с выводом сообщения в отдельном окне.

15.02.2019    38481    0    ids79    47    

Автоматические и управляемые блокировки применительно к типовым конфигурациям 1С

Математика и алгоритмы Практика программирования v8 v8::blocking 1cv8.cf Бесплатно (free)

Основные принципы работы с режимами автоматических и управляемых блокировок в 1С Предприятие 8. Теория и применение в типовых конфигурациях: БП, УТ, ЕРП

10.11.2018    30530    0    ids79    40    

Как я начал администрировать сервер 1С: Предприятие 8.3 с телефона Промо

Администрирование данных 1С Мобильная разработка v8 Бесплатно (free)

Развитие инструментов управления кластером серверов 1С:Предприятие 8.3.

14.04.2017    57799    0    user700211_a.straltsou    27    

Git + 1С. Часть 1. Как подключиться к команде разработки и начать использовать Git

Инструментарий разработчика Управление проектом v8 1cv8.cf Бесплатно (free)

Первая статья из цикла инструкций по работе с Git в 1С-разработке. Рассмотрим, как настроить рабочее место, как получить свою "копию" проекта для разработки и приступить к полезным действиям. Все примеры будут изложены в рамках трёх практических кейсов: 1. Моя команда дорабатывает типовую конфигурацию, использует приватный репозиторий на BitBucket, в котором версионируются внешние отчеты/обработки, расширения конфигураций и правила обмена; 2. Я участвую в стартап-команде, которая разрабатывает свою конфигурацию с использованием Git и GitLab; 3. Я принимаю участие в развитии OpenSource-продукта на GitHub как заинтересованный разработчик (контрибьютор).

18.10.2018    57679    0    stas_ganiev    73    

Приемы работы с СКД: делаем за 5 минут то, на что у других уйдет час

Практика программирования Инструментарий разработчика v8::СКД Бесплатно (free)

Сергей Наумов делится опытом нестандартного использования системы компоновки данных. Он рассказывает о построении сложных отчетов с помощью функций СКД, описывает преимущества использования компоновки в коде для значительного сокращения строк кода и времени на решение задач, а также рассказывает про отладку компоновки и возможности оптимизации ее работы.

03.09.2018    41460    0    SergeyN    26    

Из Excel в 1С запросом

Загрузка и выгрузка в Excel v8 1cv8.cf Бесплатно (free)

... ну, конечно, не прям так типовым языком запросов, а расширенным языком запросов. Речь пойдет о том, как "залить" данные в таблицы 1С и не пилить при этом бесконечного количества наколеночных обработок.

14.08.2018    18711    0    m-rv    5    

Копирование числовых ячеек из 1С в Excel Промо

Загрузка и выгрузка в Excel Администрирование данных 1С v8 1cv8.cf Бесплатно (free)

Решение проблемы, когда значения скопированных ячеек из табличных документов 1С в Excel воспринимаются последним как текст, т.е. без дополнительного форматирования значений невозможно применить арифметические операции. Поводом для публикации послужило понимание того, что целое предприятие с более сотней активных пользователей уже на протяжении года мучилось с такой, казалось бы на первый взгляд, тривиальной проблемой. Варианты решения, предложенные специалистами helpdesk, обслуживающими данное предприятие, а так же многочисленные обсуждения на форумах, только подтвердили убеждение в необходимости описания способа, который позволил мне качественно и быстро справиться с ситуацией.

15.01.2019    20153    0    itriot11    22    

Тестер: частые вопросы

Практика программирования v8 Бесплатно (free)

Ошибкам бой - тесты норма жизни!

25.07.2018    26215    0    grumagargler    26    

[Шпаргалка] Свой заголовок отчету на СКД с параметрами, картинками (без программирования)

Работа с интерфейсом v8::СКД 1cv8.cf Бесплатно (free)

Если возникла необходимость в заголовок отчета вывести дополнительную информацию к примеру дату формирования отчета, тогда данная шпаргалка поможет вам быстро это сделать.

23.07.2018    41892    0    rpgshnik    59    

Повышаем эффективность разработки правил обмена

Практика программирования Перенос данных из 1C8 в 1C8 v8 КД Бесплатно (free)

Как повысить скорость и качество разработки правил обмена? Как вести групповую разработку правил обмена? Как облегчить сопровождение правил обмена после передачи в эксплуатацию? Об этом и многом другом вы можете узнать из этой статьи.

25.06.2018    26092    0    olegtymko    47    

Обмен данными. Консистентность vs Многопоточность Промо

Интеграция v8 1cv8.cf Бесплатно (free)

Рассмотрим теоретические основы обмена данными. Какие бывают обмены, какие гарантии при этом даются, зачем идти на компромиссы и что при этом может пойти не так. Есть ли идеальная схема?

03.09.2019    10467    0    m-rv    1    

Как сделать запрос на изменение данных

Практика программирования v8 v8::Запросы 1cv8.cf Бесплатно (free)

В статье приведены особенности внутренней архитектуры и примеры работы с расширением языка запросов 1С.

01.06.2018    27391    0    m-rv    21    

Строим графы средствами 1С (без GraphViz)

Практика программирования v8 Бесплатно (free)

Множество статей на Инфостарте описывают, как работать с компонентой GraphViz, чтобы построить ориентированный граф. Но практически нет материалов, как работать с такими графами средствами 1С. Сегодня я расскажу, как красиво строить графы с минимальным пересечением. Нам этот метод пригодился для отрисовки алгоритмов в БИТ.Финансе, т.к. типовой механизм не устраивал. Еще это может быть полезно для визуализации различных зависимостей: расчета себестоимости, графы аффилированности компаний и т.д. Надеюсь, эта статья поможет сделать мир 1С красивее и гармоничней:) Итак, поехали...

23.05.2018    22857    0    slozhenikin_com    20    

Распределение расходов пропорционально продажам

Финансовый учет и бюджетирование (FRP) Учет доходов и расходов Практика программирования Финансовый учет и бюджетирование (FRP) Учет доходов и расходов v8 v8::ОУ УТ10 УУ Бесплатно (free)

Финансовая модель. Распределение административных расходов по подразделениям пропорционально продажам за месяц. Дополнительные реквизиты против бизнес-процессов!

13.05.2018    16983    0    Rustig    9    

Использование программных перечислений, ч.1: строковые константы Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Часто ли у вас возникает необходимость в коде выполнять сравнение на строку?

10.12.2016    34135    0    unichkin    45    

Универсальный обмен между идентичными конфигурациями через REST интерфейс OData. Часть І: Справочники

Перенос данных из 1C8 в 1C8 v8 Бесплатно (free)

Сейчас все чаще интеграции различных конфигураций проектируются через HTTP-сервисы - они и работают быстрее, и "войти" в режим отладки гораздо проще, тем самым обойдя "черный ящик" универсального обмена через xml, например. Более года назад я начал работать в компании, в которой разработчики работали с конфигурациями 1С в режиме совместимости еще 8.2.16 (менять режим совместимости в типичных базах мы не хотели) - а как Вы наверное знаете, если интересовались HTTP-сервисами в 1С, их использование в режиме совместимости 8.3.4 и ниже недопустимо - и здесь я уже не надеялся на разработку и использование HTTP-сервисов. Но позже меня заинтересовал такой "сервис" как REST интерфейс OData, так как его можно использовать не меняя режим совместимости конфигурации - именно он и стал для меня идеальным вариантом решения "нетривиальных" задач.

11.05.2018    21059    0    V.Stavinsky    11    

Минимализмы 3

Практика программирования Универсальные функции v8 Бесплатно (free)

Очередная серия "минимализмов" [http://infostart.ru/public/306536/, https://infostart.ru/public/460935/]. Также, как и в предыдущих статьях, здесь приведена подборка коротких оригинальных авторских решений некоторых задач. Ранее эти решения были разбросаны по моим комментариям к чужим публикациям.

19.02.2018    43813    0    ildarovich    45    

Этюды по программированию. Взаимодействие с Microsoft Word

Практика программирования v8 Бесплатно (free)

Часто приходится заниматься созданием сложных документов Word с таблицами, вложенными фрагментами, хитрым оформлением и прочими радостями жизни. Это - попытка как-то структурировать полученный опыт, чтобы не приходилось перерывать ворох старых обработок в поисках крупиц истины. Надеюсь, эта статья будет полезна и Вам.

11.12.2017    30884    0    milkers    23    

Вспомогательные инструкции в коде 1С Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    26117    0    tormozit    100    

Метод формирования движений в типовых регистрах нетиповыми регистраторами

Практика программирования v8 1cv8.cf Бесплатно (free)

Вариант решения задач с проведением по типовым регистрам нетиповыми регистраторами. Зачем - чтобы при сравнении конфигурации не обращать внимание на свойства регистров и исключить вероятность допущения горькой оплошности при обновлении информационных баз, заменив типы регистраторов основной конфигурации типами конфигурации поставщика. Для программных продуктов, имеющих в своем составе метаданных документ "Корректировка регистров"("Корректировка записей регистров").

05.12.2017    25704    0    itriot11    34    

1С: Конвертация данных 3. Инструкции и примеры. EnterpriseData (универсальный формат обмена)

Перенос данных из 1C8 в 1C8 Практика программирования Обмен через XML v8 КД Бесплатно (free)

Что такое КД3? Как начать использовать? Полезные дополнения к документации. Что нужно исправить в типовых обработках и конфигурации. Как изменить правила обмена не снимая конфигурацию с поддержки. Как отлаживать правила обмена?

19.11.2017    176576    0    MaxS    270    

Как работает серверный вызов в 1С

Математика и алгоритмы v8::УФ Бесплатно (free)

Клиент-серверная архитектура заложена в платформе изначально — со времен «1С:Предприятие 8.0». Однако при разработке на 8.0 и 8.1 о разделении кода на клиентскую и серверную часть можно было не заботиться, поскольку на клиенте (на толстом клиенте) был доступен тот же функционал, что и на сервере. Всё изменилось с выходом платформы «1С:Предприятие 8.2», когда появился тонкий клиент. Теперь на клиенте доступен один функционал, на сервере — другой. Клиент и сервер «общаются» между собой с помощью серверного вызова. Конечно, это усложнило процесс разработки, но с другой стороны – можно создавать более оптимальные (быстрые) решения, поскольку все сложные задачи выполняются на сервере.

18.11.2017    51922    0    pahich    82    

Оформление и рефакторинг сложных логических выражений Промо

Практика программирования v8 Россия Бесплатно (free)

В сложных логических выражениях нередко самому автору спустя какое-то время тяжело разобраться, не говоря уже о других программистах. Предлагаемая методика позволяет повысить наглядность таких выражений путем оформления в виде И-ИЛИ дерева и одновременно выполнять их рефакторинг.

20.09.2012    73627    0    tormozit    129    

Программные перечисления, ч.2: приемы кэширования при разработке

Практика программирования v8 Бесплатно (free)

Все знают, что такое кэш, и зачем он нужен. Но в 1С разработчик обычно использует кэширование только на уровне конфигурации, а в какой-нибудь обработке скорее ломает голову над запросом - как получить все данные за один заход... Хочется рассказать о том, как можно добиться хороших результатов с стратегией "разделяй и властвуй".

30.10.2017    25669    0    unichkin    18    

Легкий способ обновления измененной конфигурации

Инструментарий разработчика v8 Бесплатно (free)

Легкий способ обновления измененной конфигурации. Сервис подготовки расширения конфигурации

25.10.2017    22069    0    avk72    63    

Работа с Excel

Практика программирования Загрузка и выгрузка в Excel v8 Бесплатно (free)

Собрал различные полезности для работы с Excel из 1С. Иногда приходится форматировать документ Excel программно из 1С. Так вот, чтобы не искать постоянно на просторах интернета как сделать левое выравнивание в ячейке Excel из 1С и т.п. решил опубликовать это...

23.10.2017    38945    0    arakelyan    39    

Запись значения в поле ввода/формы со срабатыванием события ПриИзменении Промо

Практика программирования v8 1cv8.cf Россия Бесплатно (free)

Иногда возникает необходимость после записи значения в какое либо поле ввода/формы вызвать для него обработчик события ПриИзменении, а о вызове самого события приходится только мечтать. В этой статье приводится программный способ вызова этого события.

11.07.2007    44710    0    tormozit    38    

Подбор в управляемой форме - что может быть проще?

Работа с интерфейсом v8::УФ 1cv8.cf Бесплатно (free)

Технологии модальности сейчас меняются на технологии асинхронности, многопоточности и прочие дивные вещи, что, в свою очередь, заставляет людей еще чаще спрашивать о том, что да как в этой новой нелегкой жизни. Разбираемся!

19.09.2017    37529    0    starik-2005    64    

Ускоряем 1С: модули с повторным использованием возвращаемых значений

Практика программирования v8 Бесплатно (free)

По роду своей деятельности, мне часто приходится обсуждать с программистами детали реализации той или иной функциональности. Очень часто, разговаривая даже с квалифицированными специалистами я сталкиваюсь с незнанием сути платформенной функциональности Повторного использования возвращаемых значений общих модулей. В данной статье я постараюсь дать краткий обзор и основные особенности этой функциональности.

04.09.2017    49972    0    m-rv    60    

Как просто запомнить алгоритм программного вывода в СКД

Практика программирования v8 v8::СКД Бесплатно (free)

Порой нужно быстро вывести на экран таблицу значений, используя СКД \ получить данные отчета в таблицу значений.. Несмотря на очевидность алгоритма - раньше мне проще было загуглить программный вывод, благо эта инфа есть везде. Но постепенно понял как его можно быстро вспомнить, и лишний раз ничего не искать. Конечно эта статья не для Гуру :) Но я думаю - что любой неопытный в СКД программист сделает для себя небольшое открытие...

01.09.2017    47010    0    unichkin    15    

Как сделать из &НаКлиентеНаСервереБезКонтекста почти &НаКлиентеНаСервере Промо

Практика программирования v8 1cv8.cf Россия Бесплатно (free)

Как сделать метод формы, доступный на клиенте и на сервере одновременно, и сохранить при этом удобство разработки

10.09.2017    40469    0    tormozit    72    

Выгрузка документа по условию Промо

Практика программирования Разработка v8 Бесплатно (free)

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    14138    0    m-rv    2